Setup

Equations for (Subscript[E, τ]) and the sections (Subscript[ψ, i]):

alpha1=0;
a=16τ^6;
b=1-6τ^2-3τ^4;
c[x_]:=a(x-alpha1)+b(x-alpha1)^2+(x-alpha1)^3;
(*The variable t will stand for 1/(x-alpha1), and will be substituted for this later*)
psi[0]=(x-alpha1)*Z^6+a*t;
psi[1]=(x-alpha1)^2*Z^6+a^2*t^2;
psi[2]=(x-alpha1)*Z^5+a*t*Z;
psi[3]=y*Z^5-a*y*t^2*Z;
psi[4]=Z^4+Z^2;
psi[5]=(x-alpha1)*Z^4+a*t*Z^2;
psi[6]=Z^3;

Equations for special sections (Subscript[λ, i]):

λ[0]=Table[psi[i],{i,0,6}].{1,0,1,0,0,0,0};
λ[1]=Table[psi[i],{i,0,6}].{1,0,0,0,0,-1,0};
λ[2]=Table[psi[i],{i,0,6}].{0,0,0,0,1,0,2};
λ[3]=Table[psi[i],{i,0,6}].{-8τ^2(1+τ^2),1,0,0,4τ^4(1+4τ^2+τ^4),0,(-2)*4τ^4(1+4τ^2+τ^4)};

This is the equation of the family with an (Subscript[A, 5])-singularity (denoted by μ(τ) in the article) at the point (R,(1:1)), whose local coordinates are (x,Z)=(4τ^3,1). Since we only care about the family locally at the point, we clear denominators.

a5fam=Simplify[(x-alpha1)^2*({4 (((1-τ))^2) (τ^2) (1+14 τ+34 (τ^2)+14 (τ^3)+(τ^4)),8 (τ^3) (3+28 τ+34 (τ^2)+28 (τ^3)+3 (τ^4)),-8 (τ^6) (1-52 τ-90 (τ^2)-52 (τ^3)+(τ^4)),(((1+6 τ+(τ^2)))^2)}.{λ[0],λ[1],λ[2],λ[3]}/.t->1/(x-alpha1))];

Equation of the family in local coordinates near the point (R,(1:1)):

a5local=a5fam/.{x->u+4τ^3,Z->v+1};

Given a polynomial f(u,v), the following will give the coefficient of (u^i)(v^j) and print its k-jet at (0,0):

coef[i_,j_,f_]:=Factor[(1/i!)(1/j!)D[f,{u,i},{v,j}]/.{u->0,v->0}];
jet[k_,f_]:=
(
For[i=0,i≤k,i++,
For[j=0,j≤i,j++,
Print[coef[i-j,j,f], " * ", u^(i-j) v^j,"+"];
];
];
Print["terms of higher order"];
)

The following shows that the a generic member of the family has a double point at (R,(1:1)) and that the Hessian has rank 1:

jet[3,a5local]

MatrixForm[Factor[D[a5local,{{u,v},2}]/.{u->0,v->0}]]

First blow up

We now blow up (u,v)-plane at the origin and examine the pullback of the family. Recall that is defined by {(u,v,((Subscript[s, 0]):(Subscript[s, 1]))) ∈ (A^1)×(P^1): (Subscript[s, 1])u=(Subscript[s, 0])v}, and so the two coordinate patches may be given by (Subscript[s, 1])≠0 (where (Subscript[s, 1])=1 and u=(Subscript[s, 0])v) and (Subscript[s, 0])≠0 (where (Subscript[s, 0])=1 and v=(Subscript[s, 1])u):

First we calculate the equation of the proper transform of the family, and then compute where it intersects the exceptional divisor:

(a5local/.{u->s0 v})/v^2//Factor;
Factor[%/.v->0]

((a5local/.{v->s1 u})/u^2)//Factor;
Factor[%/.u->0]

Hence the proper transform intersects the exceptional divisor at the point (u,v,((Subscript[s, 0]):(Subscript[s, 1])))=(0,0,((Subscript[s, 0]):1)), where (Subscript[s, 0]) is given by:

Factor[Solve[s0-(τ^2)+2 (τ^3)-(τ^4)==0,s0]]

We will now localize the proper transform at this point, abusing notation by using (u,v) for the local coordinates again:

proper1=Factor[Factor[(a5local/.{u->s0 v})/v^2]/.{s0->u+(((-1+τ))^2) (τ^2)}];
jet[3,proper1]

We see from this that the proper transform of the family still has one singular point.  It is also a degenerate singular point:

MatrixForm[Factor[D[proper1,{{u,v},2}]/.{u->0,v->0}]]
Factor[Det[D[proper1,{{u,v},2}]/.{u->0,v->0}]]

Second blow up

Having localized the proper transform from the first blow up at its singular point, we now blow up again exactly as before:

(proper1/.{u->s0 v})/v^2//Factor;
Factor[%/.v->0]

((proper1/.{v->s1 u})/u^2)//Factor;
Factor[%/.u->0]

In this second blow up, we see that the proper transform meets the exceptional divisor in exactly one point:

Factor[Solve[8 s0-τ+8 (τ^2)-14 (τ^3)+8 (τ^4)-(τ^5)==0,s0]]

Again we localize the (new) proper transform at this point:

proper2=Factor[Factor[(proper1/.{u->s0 v})/v^2]/.{s0->u+(1/8) (((-1+τ))^2) τ (1-6 τ+(τ^2))}];
jet[3,proper2]

So the proper transform still has a singular point after the second blow up, and we need to blow up once more to resolve it.  But we can tell that the third blow up will be the last one because the singularity that we have just produced is also (generically) nondegenerate:

MatrixForm[Factor[D[proper2,{{u,v},2}]/.{u->0,v->0}]]
Factor[Det[D[proper2,{{u,v},2}]/.{u->0,v->0}]]

Third blow up

(proper2/.{u->s0 v})/v^2//Factor;
Factor[%/.v->0]

((proper2/.{v->s1 u})/u^2)//Factor;
Factor[%/.u->0]

Factor[Discriminant[256 (s0^2)-τ+288 s0 τ-1024 (s0^2) τ+35 (τ^2)+1152 s0 (τ^2)+1536 (s0^2) (τ^2)+17 (τ^3)+14976 s0 (τ^3)-1024 (s0^2) (τ^3)+1238 (τ^4)+23424 s0 (τ^4)+256 (s0^2) (τ^4)-5677 (τ^5)+51392 s0 (τ^5)+1901 (τ^6)+23424 s0 (τ^6)-10723 (τ^7)+14976 s0 (τ^7)+26420 (τ^8)+1152 s0 (τ^8)-10723 (τ^9)+288 s0 (τ^9)+1901 (τ^10)-5677 (τ^11)+1238 (τ^12)+17 (τ^13)+35 (τ^14)-(τ^15),s0]]

The conclusion of this calculation is that, after the third blow up, the proper transform of the family will meet the third exceptional divisor in 2 points.  (These points are defined over k((Sqrt[τ])).)  This is consistent with the conclusion from the end of the second blow up.  General theory tells us that the proper transform will be smooth at both of these points.  But one can also do a direct check by specializing to some square value of τ such as τ=9 (since the smoothness is an open property in the variable τ).

Solve[((256 (s0^2)-τ+288 s0 τ-1024 (s0^2) τ+35 (τ^2)+1152 s0 (τ^2)+1536 (s0^2) (τ^2)+17 (τ^3)+14976 s0 (τ^3)-1024 (s0^2) (τ^3)+1238 (τ^4)+23424 s0 (τ^4)+256 (s0^2) (τ^4)-5677 (τ^5)+51392 s0 (τ^5)+1901 (τ^6)+23424 s0 (τ^6)-10723 (τ^7)+14976 s0 (τ^7)+26420 (τ^8)+1152 s0 (τ^8)-10723 (τ^9)+288 s0 (τ^9)+1901 (τ^10)-5677 (τ^11)+1238 (τ^12)+17 (τ^13)+35 (τ^14)-(τ^15)==0)/.τ->9),s0]

proper3special=Factor[Factor[(proper2/.{u->s0 v})/v^2]/.{τ->9,s0->-233616}];
jet[2,proper3special]

In any case, the conclusion is that each member of the original family of curves (in the variable τ) has an (Subscript[A, 5])-singularity at the point (R,(1:1)) whenever τ (1+τ) (1+6 τ+(τ^2))≠0.